gnuplot demo script: world.dem

#
# $Id: world.dem,v 1.9 2004/09/28 06:06:10 sfeam Exp $
#
#
set title "Gnuplot Correspondences"
unset key
unset border
unset yzeroaxis
unset xtics
unset ytics
#
# plot world map and correspondent locations as a +
plot 'world.dat' with lines lt 3 , 'world.cor' with points lt 1 pt 2
set title ""
set key on
set border
set yzeroaxis
set xtics
set ytics

Click here for minimal script to generate this plot

#
# plot a '3D version using spherical coordinate system' of the world.
set angles degrees
set title "3D version using spherical coordinate system"
set ticslevel 0
set view 70,40,0.8,1.2
set mapping spherical
set parametric
set samples 32
set isosamples 9
set urange [-90:90]
set vrange [0:360]
splot cos(u)*cos(v),cos(u)*sin(v),sin(u) with lines lt 5 ,\
'world.dat' with lines lt 3 , 'world.cor' with points lt 1 pt 2

Click here for minimal script to generate this plot

# HBB 20000715: new demo:
# same plot, but with hidden3d active, plus axes through the
# poles:
set title "3D solid version through hiddenlining"
set hidden3d
set arrow from 0,0,-1.2 to 0,0,1.2 lt 5 lw 2
set arrow from -1.2, 0, 0 to 1.2, 0, 0 nohead lt 5 lw 1 
set arrow from 0, -1.2, 0 to 0, 1.2, 0 nohead lt 5 lw 1
splot cos(u)*cos(v),-cos(u)*sin(v),sin(u) with lines lt 5 ,\
'world.dat' u 1:2:(1.001) with lines lt 3 , 'world.cor' with points lt 1 pt 2

Click here for minimal script to generate this plot

unset arrow
unset hidden

#
# plot a '3D version using cylindrical coordinate system' of the world.
set title "3D version using cylindrical coordinate system"
set ticslevel 0.0
set view 70,40,0.8,1.2
set mapping cylindrical
set parametric
set samples 32
set isosamples 9
set urange [-180:180]
set vrange [-90:90]
splot cos(u),sin(u),v with lines lt 5 ,\
'world.dat' with lines lt 3 , 'world.cor' with points lt 1 pt 2

Click here for minimal script to generate this plot

reset